How to update Dedicated Server (for Dummies)

[tm2meyer]

Hi, I'm new to all of this I got a dedicated server running however I am not sure how to update it. if anyone know how please let me know. I am unable to play on the server at this time now. I have done about an hour or 2 of digging and either nothing makes sense to me or its not working.

[Eggonomicon]

I use a custom bat file.

rem ___________________
rem BEGIN CONFIGURATION
rem ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
set SteamCMD_Dir=C:\CitadelServer\SteamCMD
rem ^ Location to dirctory containing steamcmd.exe ^
set Server_Dir=C:\CitadelServer
rem ^ Location to directory that the Citadel Server will be installed in ^
set Executable_Dir=C:\CitadelServer\Citadel\Binaries\Win64
rem ^ Location to directory containing the following executable ^
set Server_Executable=CitadelServer.exe
rem ________________
rem BEGIN BATCH CODE
rem ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
cls
@echo off
title Citadel Server Watchdog 
echo DO NOT CLOSE THIS WINDOW!
echo.

:start
tasklist /nh /fi "Imagename eq %Server_Executable%" | find "CitadelServer"
if ERRORLEVEL=1 goto update
if ERRORLEVEL=0 goto close

:update
echo Checking For Update
start "" /b /w /high "%SteamCMD_Dir%\steamcmd.exe" +login anonymous +force_install_dir "%Server_Dir%" +app_update 489650 validate +quit
echo.
echo If No Errors Exist, The Server Has Been Started! Check Task Manager
echo.
echo Waiting For Crash...
cd "%Executable_Dir%"
start "" /w /high "%Server_Executable%" -nosteamclient -server &:: Using "-log" Will Prevent Automatic Crash Detection
echo Crash Detected!
echo.
echo CTRL+C To Freeze Before Restarting
timeout /t 15
goto start

:close
echo.
echo !ERROR! SERVER ALREADY RUNNING! SHUTDOWN WILL COMMENCE
taskkill /im "%Server_Executable%" /f /t
timeout /t 3
goto start

Naturally you have to edit your directories.

I also use some custom PowerShell scripts but I host many games on my dedicated servers, but this should do the job for you.


~Eggo