Portable mode

[AyrA]

The game itself (apart from the save file location) is portable. If you want it on the go, copy the game folder, which contains your executable to your desktop (I recommend using the DRM free version for this).

Create a file in the folder and name it run.bat.

Content of the File:

@ECHO OFF
SET CURR=%CD%
GOTO INSTALL

:INSTALL
REM installs portable saves to appdata and backs up local game
CD /D "%APPDATA%"
REM failed last run check
IF EXIST _3909 GOTO FAILED
REM Backup local game
IF EXIST 3909 REN 3909 _3909
REM copy portable save
IF EXIST "%CURR%\data" XCOPY "%CURR%\data" 3909 /K /R /E /I /S /C /H
GOTO RUN

:FAILED
REM fixes a previous crashed run and restores
REM potentially existing content from local game
IF EXIST 3909 RD "%CURR%\data" /S /Q
MOVE 3909 "%CURR%\data"
RD 3909 /S /Q
REN _3909 3909
GOTO INSTALL

:RUN
REM runs the application
CD /D %CURR%
CLS
ECHO Do not close this window, or you will ♥♥♥♥ up
ECHO an eventually existing installed version.
PapersPlease.exe
GOTO SAVE

:SAVE
REM saves portable settings to folder and restores local game
CD /D %APPDATA%
IF EXIST "%CURR%\data" RD "%CURR%\data" /S /Q
IF EXIST 3909 MOVE 3909 "%CURR%\data"
IF EXIST _3909 REN _3909 3909

:END
SET CURR=

if you want to be able to manage your saves (copy between portable and installed mode),
create a file named manage.bat with this content:

@ECHO OFF
ECHO Select clone option
ECHO To use option A or B, you should delete the destination first with C or D
ECHO.
ECHO Actions cannot be undone!
ECHO.
ECHO [A]=Portable -^> Local
ECHO [B]=Local    -^> Portable
ECHO [C]=Portable -^> *Trash*
ECHO [D]=Local    -^> *Trash*
ECHO [E]=Exit
ECHO.
CHOICE /C ABCDE
IF "%ERRORLEVEL%"=="5" GOTO END
IF "%ERRORLEVEL%"=="4" RD "%APPDATA%\3909" /S /Q
IF "%ERRORLEVEL%"=="3" RD data /S /Q
IF "%ERRORLEVEL%"=="2" XCOPY "%APPDATA%\3909" data /K /R /E /I /S /C /H
IF "%ERRORLEVEL%"=="1" XCOPY data "%APPDATA%\3909" /K /R /E /I /S /C /H
GOTO END

:END
PAUSE

[Sitting Bear]

lollllllllllllol

[AyrA]

Originally posted by jackel_vii:

lollllllllllllol

You stop laughing, when you see me running my portable skyrim.
Batch files are a wonderful invention

[AyrA]

Originally posted by jackel_vii:

johntotttotttttottototootototjojojojoioi

I see the level of this discussion rising...

[Sitting Bear]

wowlololoololololoololyoyoyooyototootototototootogggggogogoog

[Captain Kiwii]

Thank's a lot dude, Exactly what i was looking for.