Highlight Unseen Choices

Installation

Ren'py has a built-in feature to show you which choices you've seen and which are new, but Slay the Princess doesn't use it by default. This is how to manually enable it:

1. Open your game installation folder
2. Navigate to "Slay the Princess/game/". There should be a file in the directory named "script_version.txt"
3. Save the text below as "Slay the Princess/game/choicemod.rpy"

choicemod.rpy

init offset = 1

style choice_button_new is choice_button
style choice_button_new_text is choice_button_text:
    idle_color "#ffD"
    hover_color "#DB0"

screen choice(items):
    style_prefix "choice"
    default yadj = ui.adjustment()
    key "K_UP" action ScrollViewport(yadj, 'up')
    key "K_DOWN" action ScrollViewport(yadj, 'down')
    key "pad_lefty_neg" action ScrollViewport(yadj, 'up')
    key "pad_dpup_press" action ScrollViewport(yadj, 'up')
    key "pad_dpdown_press" action ScrollViewport(yadj, 'down')
    key "pad_lefty_pos" action ScrollViewport(yadj, 'down')
    #add "gui/choices_backdrop_test.png"
    add "gui/choices_backdrop.png"
    viewport yadjustment yadj:
        draggable True
        mousewheel True
        scrollbars "vertical"
        xalign 0.0
        xsize 430
        ysize 650
        xpos 1480
        ypos 25
        vbox:
            for idx, i in enumerate(items):
                textbutton i.caption:
                    if not i.chosen:
                        style "choice_button_new"
                    action i.action
                    default_focus (idx == 0)

Preview

Unseen choice is outlined in yellow
Hovered choice is yellow

[Hanabishi]

No, still works fine with the Pristine Cut.

[Luke Hatsune]

The game seems to be giving me an error when I try to add it. Could the latest update have messed it up?

[Hanabishi]

It simply highlights dialog options you have never clicked before. No more, no less.
It also does not account non-linearity of the game.

[I/O Netrunner]

Does this highlight choices that have new choices locked behind them or just new choices themselves?

[Cubic John]

There's also an exploitable bug in the game (as of The Pristine Cut's initial release) where if you load another save file WHILE you're at a set of choices in which there are greyed-out options that you can't select (such as during The Tower or The Moment of Clarity, or in parts of Chapter I during later loops where some options are blocked off), you will then be able to see all not-currently-available options (also as greyed-out text) for all choices you go through (until a chapter transition or maybe certain other events that reset the behavior to normal). In other words, it puts you into what seems to be some kind of debug mode that shows all options that could possibly be available at a particular choice scene. I was trying to find if there were any guides out there already that mentioned this, and at first I thought that that was what this one was about.

[oh no]

I can also confirm that it's working with Pristine Cut, thanks for this!

[Hanabishi]

Works for me.

[Gibbeh64]

Works! Just make sure when you save-as, you change it from a "txt" files to "all files" and you should be golden

[Trap God]

Another info to add for the others is the fact that the file should really be .rpy (true one not .txt), you need to go to modify that into files :

click on the "..."
Select "option"
Go to "View" part
click on "Hide extensions for known files types"
Apply
Change the name into choicemod.rpy
it should modify the format and will get a "warning" that you change the format of the file

You can after that click on the "Hide extensions for known files types" to not be annoyed

With that it works perfectly fine for me

[Hanabishi]

Consider that if you already played the game extensively, it could be harder to actually stumble upon choices you haven't seen before. It works effectively the same as the skip function.