How To Enable Steam Overlay

Enable the steam overlay for Tomb Raider Legend and other games.

How To

Create a new text file on your computer and rename the text file extension from .txt to .bat
eg. ForceSteamOverlay.bat
Right click -> edit the new batch file. Copy the code from the box down below, paste it inside the new batch file and save it.
To use, double click on the batch file.

Then just start Tomb Raider Legend (or any other game in the exe list) as you usually would in Steam. It'll recognise the game and enable the Steam overlay. You can now use Steam chat, screenshot functionality etc.

@Echo off

:: Alter this path if your Steam installation lies somewhere else.
set steamPath=C:\Program Files (x86)\Steam

:: List of games tried and working.
:: Fallout (high resolution)   > falloutwHR.exe
:: Fallout (classic)           > FALLOUTW.EXE
:: Fallout 2 (high resolution) > fallout2HR.exe
:: Tomb Raider Legend          > trl.exe
:: Tomb Raider Underwold       > tru.exe

:: Add game exe's here, seperated with a space.
set exes=falloutwHR.exe FALLOUTW.EXE fallout2HR.exe trl.exe tru.exe

:: Not really necessary but as a precaution,
:: give the game some breathing room before starting the overlay. (in seconds)
set delay=3


:: No need to alter anything below this line ::
set gamePID=
set steamPID=

echo Waiting on game start..

: Search
REM Grabbing and feeding the Steam pid in the command eliminates occurance of overlay not popping sometimes, no need for game app ID.
REM Do it here in the search to be sure, in case of this batch being ran before Steam was started.
if defined steamPID (goto SkipSteamSearch) else (for /f "tokens=2" %%s in ('tasklist ^| findstr /i "steam.exe" 2^>NUL') do set steamPID=%%s)

: SkipSteamSearch
for %%e in (%exes%) do (for /f "tokens=2" %%p in ('tasklist ^| findstr /i "%%e" 2^>NUL') do set gamePID=%%p)
if not defined gamePID (timeout 3 /nobreak > nul & goto Search) else (echo Game started) & (echo Forcing overlay)
timeout %delay% /nobreak > nul
start "" "%steamPath%\GameOverlayUI.exe" -steampid %steamPID% -pid %gamePID% -manuallyclearframes 0


:: List of games tried where the overlay still don't work.
:: Fallout 2 (classic)         > fallout2.exe
:: Pharaoh + Cleopatra         > Pharaoh.exe
:: Zeus + Poseidon             > zeus.exe

Notes

If your Steam installation is located somewhere other than the default: C:\Program Files (x86)\Steam like on another hard drive for example. You will need to change the steamPath line in the script to reference your steam install location.

I've added compatibility for games in my Steam library. If you wish to add compatibility for more games, just add their exe names to the exes list.

[Padawan94]

Thanks Man

[XIII_IVAN_IIIX]

Very useful, thank you.

[Lightstylez]

Thanks for this, worked instantly with no configuration

[Ny Starfire]

Ok, I build computers and refurbish gaming console. That is hardware. That is easy to understand. I know next to nothing about software. This is close to Greek. I'm really good at reading Step By Step instructions and following them. Even if I don't understand what I am doing. If the steps are complete for each part, I can read and repeat. I have a hard time following paragraphed instructions. If it is not too much trouble, can you give these instructions in Step By Step format as if you were trying to teach a 99 year old granny how to do this? BTW I'm not a 99 year old granny, I'm a 40 year old mom. I don't even have basic understanding of software. I just know how to run a program. Not alter it, or create it.

[Calmly Frenetic]

Running the overlay this way causes "log" files to be saved in the same location as the .bat file.
For the log files to be saved in the normal location, put the .bat file in the main Steam installation folder, create a shortcut to it, and move the shortcut to the desktop.

Also worth mentioning that the .bat file can be run either before or after starting the game.

[ViWalls]

Use this instead: https://www.nma-fallout.com/threads/steamdetour-run-fallout-mods-from-steam.220425/

It requires minimal setup (just a line in parameters) and it works for every possible game, but it was originally created for classic Fallout games.

In fact, this solves too the problem with mods that have a different launcher to force steam to count played time and activate overlay plus access to screenshots. For instance, you can play Fallout Fixt and make Steam count the time played on Fallout. Another great example it's I'm playing OpenXcom but Steam understand I'm playing old X-com games. And you can run the games directly from your library with access to Steam Overlay.

It's a nice guide and solution anyways, but SteamDetour can go beyond and it's what I'm used around this subject.

In fact, I highly recommend this tool to mess with your friends computers and make their Steam account looks like playing a My Little Pony game when they are playing their favorite games xD