Key and mouse binding / remapping via AutoHotKey script

[SpringfieldMH]

#Requires AutoHotkey v2.0
; Can be obtained for free from https://www.autohotkey.com/

; This script tested on Windows 10 Pro 64 bit.

; CAUTION: Use at own risk. Have made good faith effort
;          to limit effects to specified game(s),
;          but may unintentionally affect other stuff.

; TERMINATION:
;          Use F12 function key (see below) to terminate.
;          Can also find its icon (green capital "H")
;          in Windows system tray (lower right corner)
;          and right click on it and exit it.

; Enable warnings to assist with debugging.
; (To disable, comment out with leading semicolon. Example: ;#Warn )
#Warn

; Optimizations  (there may be others)
SendMode "Input"      ; Fastest send method

; Maximum limit to number of hotkeys per unit of time. To avoid looping/lockup.
; (See documentation for A_HotkeyInterval and A_MaxHotkeysPerInterval)
; (originally tried 2000 and 200, 1000 and 100 seem to work better to avoid issues)
A_HotkeyInterval := 1000        ; This is the default value (milliseconds).
A_MaxHotkeysPerInterval := 60

; The AutoHotkey install includes a 'Window Spy' utility
; for determining type and name of program (game) to specify below.
; Run the game in windowed (not full screen) mode, for the following.
; Run 'Window Spy', hover over the game window, to determine the info.
; Use that info in the @Hotif condition.
; #HotIf is the optimal way to create context sensitive hotkeys and hotstrings.
; Once everything is working, can run the game full screen.

; Technically, in AutoHotkey terminology, what we are doing below
; is "remapping", rather than defining "hotkeys". 
; The use of the terms seems inconsistent in the documentation.

;   The format is Custom::GameDefault
;   Example: A::B    Hitting "A" causes game to see "B".
;   A "$" is placed first for keyboard keys,
;   to protect against hotkey looping (A::B and B::A would loop)
;   Example: $A::B
;   ("$" discussion does not apply to mouse.
;    See  https://www.autohotkey.com/docs/v2/howto/WriteHotkeys.htm
;    and  https://www.autohotkey.com/docs/v2/Hotkeys.htm#Symbols        )

; (AutoHotKey apparently translates these, behind the scenes,
;  into pairs of "hotkeys".)

            
;---- Deliver Us The Moon game by KeokeN Interactive ----
; As of late 2023.
; Deliver Us The Moon does not internally support keyboard and mouse remapping (bindings..
; (Deliver Us Mars, the sequel, does support it.)
; The developer seems to suggeest that adding internal customization is unlikely
; and suggests editing the game's Input.ini file,
; located in  C:\Users\{username}\AppData\Local\MoonMan\Saved\Config\WindowsNoEditor ,
; adding in the contents of one of these samples
;   https://pastebin.com/gNXkC4pi    (QWERTY keyboard? defaults?)
;   https://pastebin.com/F91qyzqg    (Azerty keyboard layout)
; That did not initially work for me. 
; The Input.ini file kept getting wiped/emptied. Then it didn't.
; NOTE: They neglected to mention that must remove leading "+"
; from lines that you want activated.
; A helpful article can be found at
;   https://re-actor.net/deliver-us-the-moon-how-to-rebind-keys/
; The Input.ini route may be better than AutoHotKey.

;
; Anyway, AutoHotKey remapping of both keyboard and mouse is demonstrated here.
; Remapping of gamepad is not addressed in this example. 
; AutoHotKey provides some/limited gamepad support.
; 
; (NOTE: Changes made via the Input.ini file or AutoHotKey
;        are not reflected in the game's in-game prompts.)

#HotIf (WinActive("ahk_exe MoonMan-Win64-Shipping.exe")) 
                         ; Escape (Esc, didn't change)
  $g::f                  ; Interact
                         ; Astrotool (Tab, didn't change)
  RButton::w             ; Move forward
  $f::s                  ; Move backward
  $c::a                  ; Move left
  $v::d                  ; Move right
                         ; Jump/Move Up (zero G) (Space, didn't change)
  $d::LControl           ; Move Down (zero G)
  $r::q                  ; Roll left (zero G)
  $t::e                  ; Roll right (zero G)
  $q::r                  ; Flashlight
  $w::c                  ; Control ASE (spherical robot)
                         ; Sprint (LShift, didn't change)
                         ; Walk (LControl, didn't change)
  $e::LButton            ; Zoom/Fire/Scan
                         ; Zoom/Fire/Scan (LButton, didn't change)
  $i::r                  ; Read
                         ; HIT F12 TO EXIT THIS AUTOHOTKEY SCRIPT
                         ; Message displays in windowed mode, not in full screen.
  F12::
    {
    MsgBox "
      (
        F12 was pressed.
        AutoHotKey game controls customization script 
        for Deliver Us The Moon exiting.
      )"
    ExitApp
    }
#HotIf