It's possible to play it with a Wii Remote?

[PulloverSweater]

It would be perfect :)

[MackT]

Hi Aurelio, yes it's possible to use a Wii remote but it's not officially supported due to the need of a 3rd party tool named "GlovePIE" (http://glovepie.org). What you would need is a blue tooth usb dongle and an InfraRed sensor bar (you can use the one from your Wii but you will need to power it).

1 - Install GlovePIE (we use the v0.29 but it might work with a newer one)
2 - Pair your Wiimote with your bluetooth dongle
3 - Launch GlovePIE and load the script below
4 - Play Blue Estate and do not forget to enable Raw mouse mode (Settings -> Controls -> MOUSE IN RAW MODE = YES)


This is our sample script for GlovePIE v0.29 (BlueEstate.PIE). This script is for playing on a screen of 1920x1080. You will have to edit it if you have another resolution.

//Modified for Blue Estate PC - HS(TN) 05 Feb 2015
//
//Calibration:
//To calibrate, run this program and put the Wiimote on a flat surface face-up.
//Then read the values in the debug line (next to the run button).
//Change these values until the debug line reads approx. all zeros.
var.xtrim = 6
var.ytrim = -31
var.ztrim = 6
//
//Options:
var.deadzone = 5 //distance in pixels that you have to move the wiimote in
   //order for it to register movement. Creates a "dead zone" around the pointer
   //to make it easier to click. Higher = smoother but less accurate.
var.KITTspeed = 1000 ms //delay speed for flashing LEDs. higher = slower
var.rumble = false //makes the wiimote rumble if you hit the edge of the screen
//more options to be added later

//Controls:
//Point Wiimote = Move Mouse
//D-Pad = Arrow Keys
//B-Button = Left Click
//Home = Middle Click
//A-Button = Right Click
//Plus and Minus = Control Volume
//One = Unmapped
//Two = Unmapped
//
//If the pointer hits the edge of the screen, the Wiimote will rumble a bit.
//
//The LEDs attempt to emulate KITT's grill from Knight Rider

//***Do not edit anything below this line unless you know what you are doing.***

//Movement Keys. Works for both arrow keys and WASD. 
Keyboard.Up = Wiimote.Up || Wiimote.Nunchuk.JoyY < -0.5
Keyboard.Down = Wiimote.Down || Wiimote.Nunchuk.JoyY > 0.5
Keyboard.Left = Wiimote.Left || Wiimote.Nunchuk.JoyX < -0.5
Keyboard.Right = Wiimote.Right || Wiimote.Nunchuk.JoyX > 0.5

// To fix for shipping version (-> Keyboard.Escape)
Keyboard.Space = Wiimote.Nunchuk.ZButton
Keyboard.Space = Wiimote.Nunchuk.CButton

// Use accel of nunchuk (to test !)
//if Wiimote.Nunchuk.RawAccX < 20 then
//   Keyboard.Left = true
//endif
//if Wiimote.Nunchuk.RawAccX > 20 then
//   Keyboard.Right = true
//endif
//if Wiimote.Nunchuk.RawAccY < 20 then
//   Keyboard.Up = true
//endif
//if Wiimote.Nunchuk.RawAccY > 20 then
//   Keyboard.Down = true
//endif

//Mouse Buttons
Mouse.RightButton = Wiimote.A
Mouse.LeftButton = Wiimote.B
Mouse.MiddleButton = Wiimote.Home

//Plus and Minus handle Volume
if wiimote.plus then
  volumeup = true
  wait 60 ms
  volumeup = false
endif
if wiimote.minus then
  volumedown = true
  wait 60 ms
  volumedown = false
endif

//wiimote.One
//wiimote.Two

//LEDs look somewhat like KITT's grill from Knight Rider
if 0 = 0 then
  if var.kitt = 0 then
    wiimote.Leds = 1
  endif
  if var.kitt = 1 then
    wiimote.Leds = 3
  endif
  if var.kitt = 2 then
    wiimote.Leds = 6
  endif
  if var.kitt = 3 then
    wiimote.Leds = 12
  endif
  if var.kitt = 4 then
    wiimote.Leds = 8
  endif
  if var.kitt = 5 then
    wiimote.Leds = 12
  endif
  if var.kitt = 6 then
    wiimote.Leds = 6
  endif
  if var.kitt = 7 then
    wiimote.Leds = 3
  endif
  wait var.KITTspeed
  var.kitt = (var.kitt + 1) % 8
endif

//If the mouse reaches the end, rumble for 200 milliseconds
if var.rumble and (mouse.x = 0 or mouse.x = 1 or mouse.y = 0 or mouse.y = 1) then
  if var.rmbl = false
    wiimote.Rumble = 1
    wait 200 ms
    wiimote.Rumble = 0
  endif
  var.rmbl = true
else
  var.rmbl = false
endif

var.accx = wiimote.RawForceX + var.xtrim
var.accy = wiimote.RawForceY + var.ytrim
var.accz = wiimote.RawForceZ + var.ztrim

if wiimote.dot1vis and wiimote.dot2vis then

  if var.accy > -7 then
    var.orientation = 0
  elseif var.accy > -45 then
    if var.accx < 0 then
      var.orientation = 3
    else
      var.orientation = 1
    endif
  else
    var.orientation = 2
  endif

  if var.leftpoint = 0 then
    if var.orientation = 0 then
      if wiimote.dot1x < wiimote.dot2x then
        var.leftpoint = 1
      else
        var.leftpoint = 2
      endif
    endif
    if var.orientation = 1 then
      if wiimote.dot1y > wiimote.dot2y then
        var.leftpoint = 1
      else
        var.leftpoint = 2
      endif
    endif
    if var.orientation = 2 then
      if wiimote.dot1x > wiimote.dot2x then
        var.leftpoint = 1
      else
        var.leftpoint = 2
      endif
    endif
    if var.orientation = 3 then
      if wiimote.dot1y < wiimote.dot2y then
        var.leftpoint = 1
      else
        var.leftpoint = 2
      endif
    endif
  endif

  if var.leftpoint = 1 then
    var.fix1x = wiimote.dot1x
    var.fix1y = wiimote.dot1y
    var.fix2x = wiimote.dot2x
    var.fix2y = wiimote.dot2y
  else
    var.fix1x = wiimote.dot2x
    var.fix1y = wiimote.dot2y
    var.fix2x = wiimote.dot1x
    var.fix2y = wiimote.dot1y
  endif

  var.dx = var.fix2x - var.fix1x
  var.dy = var.fix2y - var.fix1y
  var.cx = (var.fix1x+var.fix2x)/1024.0 - 1
  var.cy = (var.fix1y+var.fix2y)/1024.0 - .75

  var.d = sqrt(var.dx*var.dx+var.dy*var.dy)

  var.dx = var.dx / var.d
  var.dy = var.dy / var.d

  var.ox = -var.dy*var.cy-var.dx*var.cx;
  var.oy = -var.dx*var.cy+var.dy*var.cx;

  var.ax = (var.ox * 1920) + (1920 / 2);// + (screen.desktopwidth / 2)
  var.ay = (-var.oy * 1080) + (1080 / 2);// + (screen.desktopheight / 2)




  var.dx = var.ax - mouse.cursorposx
  var.dy = var.ay - mouse.cursorposy

  var.d = sqrt((var.dx*var.dx)+(var.dy*var.dy))

  var.a = 180 / (200 + var.d * var.d * var.d * .001)

  if var.d <= var.deadzone then var.a = 1

  debug = var.d + " " + var.a

  var.finalx = mouse.cursorposx * var.a + var.ax * (1 - var.a)
  var.finaly = mouse.cursorposy * var.a + var.ay * (1 - var.a)


  mouse.cursorposx = var.finalx
  mouse.cursorposy = var.finaly

else

  var.leftpoint = 0

endif

//debug = var.accx + " " + var.accy + " " + var.accz

[PulloverSweater]

You're the one!

[Evil Shredder]

Thanks dev, gonna try this as soon as i get my dongle in.

[wesleyspipes]

I can 100% confirm the wiimote works perfectly with this script!

I can also 100% confirm that that game work perfectly with my AimTrack gun as well.

Thank you guys SOOOOOO much for having proper support for all these pointing devices (and raw input). You did a better job than the HOD Overkill dev team for sure.

[Tank Squirrel]

this is a good script :D
I am going to post this link in our group page :D and tell everyone to buy and support your game.

I use wiimoteoncod9.exe, it runs great as well, and no programming needed for those of you who dont want to fool with Glovepie or are scared of seeing lines of code :D

It ran ok without raw input and had free movement. IF you turn it on using the program then you have an easily always centered cursor which helps with the rapid turning that happens in the game.

[Pirlouit]

Originally posted by Yes, ThAT DaRkCoLa...:

this is a good script :D
I am going to post this link in our group page :D and tell everyone to buy and support your game.

I use wiimoteoncod9.exe, it runs great as well, and no programming needed for those of you who dont want to fool with Glovepie or are scared of seeing lines of code :D

It ran ok without raw input and had free movement. IF you turn it on using the program then you have an easily always centered cursor which helps with the rapid turning that happens in the game.

Thanks for buying and supporting the Game Yes, ThAT DaRkCola! ;)

[Tank Squirrel]

Originally posted by Moh:

Originally posted by Yes, ThAT DaRkCoLa...:

this is a good script :D
I am going to post this link in our group page :D and tell everyone to buy and support your game.

I use wiimoteoncod9.exe, it runs great as well, and no programming needed for those of you who dont want to fool with Glovepie or are scared of seeing lines of code :D

It ran ok without raw input and had free movement. IF you turn it on using the program then you have an easily always centered cursor which helps with the rapid turning that happens in the game.

Thanks for buying and supporting the Game Yes, ThAT DaRkCola! ;)

Hey update:
i am not trying to sell anything first off.
Now the dev of wiimoteoncod9 just slapped me down with my noobiness lol.

There is a setting tab that you can hit for absolute mouse control & it works perfectly without drift and dead accurate with your game. It does work regardless of resolution, so you do not have to program anything. I will make a video now and post it on your twitter so you can see.

If anyone doesn't like fooling with glovepie settings, this program is instant plug and play and it is why I use it (because Im stoopit lol).

[Tank Squirrel]

Ok the video is up. I'll post link in steam and on my page and group page :D

[匚尺乇丂匚乇几ㄒ]

Originally posted by Moh:

Originally posted by Yes, ThAT DaRkCoLa...:

this is a good script :D
I am going to post this link in our group page :D and tell everyone to buy and support your game.

I use wiimoteoncod9.exe, it runs great as well, and no programming needed for those of you who dont want to fool with Glovepie or are scared of seeing lines of code :D

It ran ok without raw input and had free movement. IF you turn it on using the program then you have an easily always centered cursor which helps with the rapid turning that happens in the game.

Thanks for buying and supporting the Game Yes, ThAT DaRkCola! ;)

Just a quick question Are you able to play Local co-op with 2 wii remotes by any chance with that program whether it be wiimoreoncod9.exe or GlovePIE?

[Tank Squirrel]

i think so yes, and am going to test this later tonight. i will post here and let you know!

[匚尺乇丂匚乇几ㄒ]

Originally posted by Yes, ThAT DaRkCoLa...:

i think so yes, and am going to test this later tonight. i will post here and let you know!

for sure man thanks

[Tank Squirrel]

Originally posted by Texas:

Originally posted by Yes, ThAT DaRkCoLa...:

i think so yes, and am going to test this later tonight. i will post here and let you know!

for sure man thanks

keep in mind:
sixense stem and wiimoteoncod9.exe are mouse emulators primarily, and not devices with device drivers.

A library for a device like xbox360 has set values. So the rules are different in making a device work and an emulation work.

This is why I used for example Toids wiimouse with 2 controllers + ppjoy to emulate a joystick control in MAME shooters like Operation Thunderbolt. It works great, because the game knows no difference and MAME UI added joystick commands to adjust the rate of response.

The problem is that joystick saturation etc isnt inherent control in some games. But you can probably find it and edit it.

Anyways- so long story short, to get it to work with two wiimotes, you need something like ppjoy and glovepie or toids wiimouse and fool the game into thinking your wiimotes are xboxs. This is what I will do tonight and test out the results in gameplay.

[匚尺乇丂匚乇几ㄒ]

Originally posted by Yes, ThAT DaRkCoLa...:

Originally posted by Texas:

for sure man thanks

keep in mind:
sixense stem and wiimoteoncod9.exe are mouse emulators primarily, and not devices with device drivers.

A library for a device like xbox360 has set values. So the rules are different in making a device work and an emulation work.

This is why I used for example Toids wiimouse with 2 controllers + ppjoy to emulate a joystick control in MAME shooters like Operation Thunderbolt. It works great, because the game knows no difference and MAME UI added joystick commands to adjust the rate of response.

The problem is that joystick saturation etc isnt inherent control in some games. But you can probably find it and edit it.

Anyways- so long story short, to get it to work with two wiimotes, you need something like ppjoy and glovepie or toids wiimouse and fool the game into thinking your wiimotes are xboxs. This is what I will do tonight and test out the results in gameplay.

alright sounds good man. I remember i had to setup 2 wiimotes for the house of the dead overkill for the Dolphin Emulator and man it was fun being able to play 2 players like that on the pc. Would like to see more rail shooters come to the pc legitly being to use motion controls. that be nice xD

[Tank Squirrel]

Ok update:

stupid error day today!

1) So my goal was to try to get Blue estate to be fooled into thinking there are two xbox controllers but they are actually wiimotes.

2) I used this time ppjoy (settings must be wiimote specific) and Toids wiimouse.

3) Toid has a nice editable script I usually used for MAME gun games where you can assign info to 1-4 wiimotes. In this case, I had two running and used the custom script with ppjoy already installed.

4) Now however, i started this process in Blue Estate and then the mouse control gets stuck in the upper left hand corner. I can regain control briefly, make a selection and move on, before it goes back to upper left hand corner.

5) after selecting 2 players and the game recognizes a 2nd player controller to start, the game cursor is now permanently stuck in the uppe rleft hand corner.

6) best part is, now the game, whenver i start it, has the cursor stuck in the left hand corner no matter what i do ahah- with no emulation turned on.


sigh, im going to bed and will try to figure this out tomorrow :D almost got it ahah

[匚尺乇丂匚乇几ㄒ]

Originally posted by Yes, ThAT DaRkCoLa...:

Ok update:

stupid error day today!

1) So my goal was to try to get Blue estate to be fooled into thinking there are two xbox controllers but they are actually wiimotes.

2) I used this time ppjoy (settings must be wiimote specific) and Toids wiimouse.

3) Toid has a nice editable script I usually used for MAME gun games where you can assign info to 1-4 wiimotes. In this case, I had two running and used the custom script with ppjoy already installed.

4) Now however, i started this process in Blue Estate and then the mouse control gets stuck in the upper left hand corner. I can regain control briefly, make a selection and move on, before it goes back to upper left hand corner.

5) after selecting 2 players and the game recognizes a 2nd player controller to start, the game cursor is now permanently stuck in the uppe rleft hand corner.

6) best part is, now the game, whenver i start it, has the cursor stuck in the left hand corner no matter what i do ahah- with no emulation turned on.


sigh, im going to bed and will try to figure this out tomorrow :D almost got it ahah

Ah damn that sucks. Well alright man let me know how that goes tomorrow man good luck.