GoG

[Bianco]

Now the Game is available on GoG. The Game will start an Work with the GoG version. (Win 10)
Why the Devs do not upate the Steam Version?

[Telebuddy]

THX!

[ThisSuXX]

I've compared GOG and Steam versions and made a small fix with all the changes I've found. you can download a batch file with a script from file hosting service or you can create this patch file yourself with the source code below. tested on Windows 10 64-bit

download links:
Yandex[disk.yandex.ru]
Google[drive.google.com]

installation:
copy batch file to your game folder and run it from there

how to create this patch file:
- open Windows Notepad
- copy all text from CODE block below (from "@echo off" to "exit /b 0")
- paste that text to Notepad
- choose File > Save As...
- choose "All files" instead of "Text documents (*.txt)" in "Save as type"
- type "ftfix.bat" (without quotes) in "File name"
- save

@echo off
setlocal enableDelayedExpansion

set /a "end=630784+1023"
set "out=Render2.dll"
set "changes=0x382A4:EB 0x38310:EB 0x38391:EB 0x3A670:EB 0x780BB:EB 0x79A51:EB"
certutil /f /encodehex "%out%" "%out%.hex" 0x40000004 >nul
call :modifyHex <"%out%.hex" >"%out%.new.hex"
certutil /f /decodehex "%out%.new.hex" "%out%" >nul
del "%out%.hex" "%out%.new.hex"

set /a "end=86016+1023"
set "out=SoundManager.dll"
set "changes=0x30D2:90 0x30D3:90 0x30D4:90 0x30D5:90 0x30D6:90 0x30D7:90"
certutil /f /encodehex "%out%" "%out%.hex" 0x40000004 >nul
call :modifyHex <"%out%.hex" >"%out%.new.hex"
certutil /f /decodehex "%out%.new.hex" "%out%" >nul
del "%out%.hex" "%out%.new.hex"

set /a "end=2633728+1023"
set "out=Tycoon.dll"
set "changes=0x27771:90 0x27772:90 0x27779:90 0x2777A:90 0x2777B:90 0x2777C:90 0x2777D:90 0x1DD8A2:70"
certutil /f /encodehex "%out%" "%out%.hex" 0x40000004 >nul
call :modifyHex <"%out%.hex" >"%out%.new.hex"
certutil /f /decodehex "%out%.new.hex" "%out%" >nul
del "%out%.hex" "%out%.new.hex"

exit /b

:modifyHex
for /f "tokens=1*" %%A in ("!changes!") do (
  set "changes=%%B"
  for /f "delims=: tokens=1,2" %%C in ("%%A") do (
    set /a "offset=%%C"
    set "value=%%D"
  )
)
for /l %%N in (1023 1023 %end%) do (
  set "ln="
  set /p "ln="
  set "ln2="
  set /p "ln2="
  set "ln3="
  set /p "ln3="
  set "ln=!ln!!ln2!!ln3!"
  if !offset! lss %%N call :modify %%N 
  echo !ln!
)
exit /b

:modify
set /a "offset=(offset-%1+1023)*3, next=offset+3"
set "ln=!ln:~0,%offset%!!value! !ln:~%next%!"
set /a "offset=0x7FFFFFFF"
for /f "tokens=1*" %%A in ("!changes!") do (
  set "changes=%%B"
  for /f "delims=: tokens=1,2" %%C in ("%%A") do (
    set /a "offset=%%C"
    set "value=%%D"
  )
)
if %offset% lss %1 goto :modify
exit /b 0

[konstanteen]

Work like a charm!

[Hanilix]

is not working for me :(

[ThisSuXX]

Originally posted by Hanilix:

is not working for me :(

I need more details than that.

[blackshark116rus]

Работает,спасибоВы единственный помогли запустить игру на Win 11

[ThisSuXX]

Originally posted by blackshark116rus:

Работает,спасибоВы единственный помогли запустить игру на Win 11

рад был помочь :)

[Ω Omega-HSC Ω]

thanks.....i download the file and haved worked

[Mamin strateg]

работает спасибо

[thetamsay]

Does this work for Windows 11 home edition as well? Because I copied it in my steam folder, ran the batch file, but nothing changes.

[ThisSuXX]

Originally posted by thetamsay:

Does this work for Windows 11 home edition as well? Because I copied it in my steam folder, ran the batch file, but nothing changes.

blackshark116rus said above that this fix worked in Win 11.

ftfix.bat must be copied to Freight Tycoon game directory (you should see Render2.dll, SoundManager.dll, Tycoon.dll files there), otherwise it won't work. if patching was successful, those dll's will change its modified date to your current time. make sure your anti-virus software don't block that script. maybe in your case you have to run it with admin privileges.

[thetamsay]

Originally posted by ThisSuXX:

Originally posted by thetamsay:

Does this work for Windows 11 home edition as well? Because I copied it in my steam folder, ran the batch file, but nothing changes.

blackshark116rus said above that this fix worked in Win 11.

ftfix.bat must be copied to Freight Tycoon game directory (you should see Render2.dll, SoundManager.dll, Tycoon.dll files there), otherwise it won't work. if patching was successful, those dll's will change its modified date to your current time. make sure your anti-virus software don't block that script. maybe in your case you have to run it with admin privileges.

Hey, thanks for the help, got it working in the end. I have a small detail to add: in case someone tried to run the game before applying the batch, they have to terminate the game first, otherwise it won't start.

[Koenigreich_Kempen]

Originally posted by ThisSuXX:

copy batch file to your game folder and run it from there

you finaly made my day. thx.

[ralf.zimmer]

Die datei lässt sich bei mir nicht runterladen. Kann die jemand zur verfügung stellen?
Danke Ralf

[ThisSuXX]

Originally posted by ralf.zimmer:

Die datei lässt sich bei mir nicht runterladen. Kann die jemand zur verfügung stellen?
Danke Ralf

i added link to G.Drive and instruction how to create this patch yourself to my original message. just make sure that your browser or antivirus don't block this file from downloading as unsafe.