[2025] Решение у кого не открывается игра

[que pasa ت]

Если при запуске игры ничего не происходит и игра просто не открывается

Закройте все программы для фикса дискорда и ютуба такие как GoodbyeDPI

Заходим в папку с игрой и создаем текстовый документ fix_rangrid.txt с текстом:

@echo off
setlocal enabledelayedexpansion

:: Check for admin privileges
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo Requesting administrative privileges...
    powershell Start-Process -FilePath "%~f0" -Verb RunAs
    exit /b
)

:: Set title
title Call of Duty Randgrid Service Fix

echo ================================================
echo Call of Duty Randgrid Service Location Fix
echo ================================================
echo This utility updates the Randgrid service after
echo moving Call of Duty's installation folder.
echo.

:: Try to automatically find Steam library folders from libraryfolders.vdf
set "STEAMPATH="
for %%I in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%I:\Program Files (x86)\Steam\steamapps\common\Call of Duty HQ\randgrid.sys" (
        set "CODPATH=%%I:\Program Files (x86)\Steam\steamapps\common\Call of Duty HQ"
    )
    if exist "%%I:\SteamLibrary\steamapps\common\Call of Duty HQ\randgrid.sys" (
        set "CODPATH=%%I:\SteamLibrary\steamapps\common\Call of Duty HQ"
    )
)

if defined CODPATH (
    echo Found Call of Duty installation at:
    echo !CODPATH!
    echo.
    choice /C YN /M "Is this the correct location"
    if !errorlevel! equ 1 (
        set "INSTALLDIR=!CODPATH!"
        goto PROCESS_SERVICE
    )
)

:MANUAL_INPUT
echo Please enter the new Steam installation folder for Call of Duty.
echo Example: D:\SteamLibrary\steamapps\common\Call of Duty HQ
echo.
set /p "INSTALLDIR=Enter the folder location: "

if "%INSTALLDIR%"=="" (
    echo No folder location was entered. Exiting.
    goto END
)

if not exist "%INSTALLDIR%\randgrid.sys" (
    echo Error: randgrid.sys not found in specified location.
    echo Please verify the folder path and try again.
    goto MANUAL_INPUT
)

:PROCESS_SERVICE
echo.
echo Updating Randgrid service location...

:: Remove existing service if present
sc query atvi-randgrid_sr >nul 2>&1
if %errorlevel% equ 0 (
    echo Removing existing Randgrid service...
    sc delete atvi-randgrid_sr
    timeout /t 2 >nul
)

:: Create service with new location
echo Installing Randgrid service at new location...
sc create atvi-randgrid_sr type= kernel binPath= "%INSTALLDIR%\randgrid.sys"
if %errorlevel% neq 0 (
    echo Failed to create the service. Please verify you are running as administrator.
    goto END
)

:: Set service permissions
echo Setting Randgrid service permissions...
sc sdset atvi-randgrid_sr D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWRPWPLOCRRC;;;IU)(A;;CCLCSWLOCRRC;;;SU)S:(AU;FA;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;WD)
if %errorlevel% neq 0 (
    echo Failed to update service permissions.
    goto END
)

echo.
echo ================================================
echo Service location updated successfully!
echo You can now launch Call of Duty.
echo ================================================

:END
echo.
pause
endlocal

После чего меняем его расширение .txt на .bat
Запускаем наш файл fix_rangrid.bat от имени администратора и нажимаем Y
Закрываем окно, пробуем запустить игру.

Если игра все так же не запускается идем дальше и открываем командную строку от имени администратора и пишем туда одну из следующих команд:
Sc Stop WinDivert или
Sc Stop WinDivert1.4

[KaiserDrewski]

а если через battle net запускаю то есть решение этой проблемы ?

[XFiko]

Не помогло :(

[Эльдар Суходрищев]

После запуска батника можно будет юзать GoodbuyeDPI/Zapret вместе с игрой или как?

[que pasa ت]

Originally posted by Январь 5.1:

После запуска батника можно будет юзать GoodbuyeDPI/Zapret вместе с игрой или как?

Пока был в игре запустил goodbyedpi и игра закрылась сама. Походу нельзя, и нужно заново выполнить второй пункт чтобы она опять запускалась

[que pasa ت]

Каждый раз после использования goodbyeDPI нужно будет прописывать в cmd команду Sc Stop WinDivert

[Хосров]

что делать если Sc Stop WinDivert при вводе выдает отказано в доступе, а на Sc Stop WinDivert1.4 пишет что служба не установлена?

[que pasa ت]

Originally posted by Хосров:

что делать если Sc Stop WinDivert при вводе выдает отказано в доступе, а на Sc Stop WinDivert1.4 пишет что служба не установлена?

От имени администратора запусти командную строку

[chibis]

у меня ваще вот как работает, перед каждым входом прописываю команду Sc Stop WinDivert, открываю файл тот и только потом игру и все работает. ( Sc Stop WinDivert открываю вне зависимости включал я запрет на дис или нет, пока не пропишу не заработает)

[NOWELEY]

Originally posted by que pasa ت:

Каждый раз после использования goodbyeDPI нужно будет прописывать в cmd команду Sc Stop WinDivert

Спасибо, помогло

[ム Degistr]

https://steamcommunity.com/app/1938090/discussions/0/604152668461489106/?tscn=1743867141

[76561198877970440]

не работает

[chibis]

а еще все таки можно попробовать запустить дис, зайти в канал и потом уже отключить запрет через cmd, и как я понял это работает( ни с кем из друзей не пробовал, но как минимум видел то что у меня чувствительность голоса, а именно кружок зеленый вокруг аватарки в канале мигает, и игра не вылетала, попробуйте мб работает так все таки )

[que pasa ت]

Originally posted by chibis:

а еще все таки можно попробовать запустить дис, зайти в канал и потом уже отключить запрет через cmd, и как я понял это работает( ни с кем из друзей не пробовал, но как минимум видел то что у меня чувствительность голоса, а именно кружок зеленый вокруг аватарки в канале мигает, и игра не вылетала, попробуйте мб работает так все таки )

Попробовал, минут через 10-30 пропадает соединение в дискорде каждый раз

[clever knight]

спасибо, работает

[nn_yad]

Originally posted by que pasa ت:

Каждый раз после использования goodbyeDPI нужно будет прописывать в cmd команду Sc Stop WinDivert

помогло, спасибо