Crashing and losing saves? Automatically backup them!

This guide will provide you a batch script so you can backup your save files before the game deletes them in a crash!

Why this script?

2k did not make a good job with their game. For some strange and odd reason, the game might crash while saving (but not only while that) and will erase (yes, really) your saves when it does, often leaving only the auto saves.

I made a little script which auto save your saves in game and can recover the files in case of crash. The next chapter will tell you how to use it, and the third one will be the script itself.

What it does?

This script can do 2 things.
It backups your Bioshock Remastered saves into a new folder called "Bioshock saves" in your home folder every minute.
In case of crash, you can ask the script to recover the files saved in "Bioshock saves" into the original bioshock saves folder and (if you want to) starts the backup routine.

How to use

Installation

• First, create a new text file and rename it "bioshock save backup.bat". Be careful to give the extension .bat, and don't get tricked by getting a .bat.txt
  
• Copypaste in it the source code in the next chapter and save it. You can save it anywhere you want since it's coded to work at any place.

Using it

• Double click the .bat file
  
• Type 1 and press ENTER
  
• Launch Bioshock Remastered.
  
• Once you finished gaming or if you crashed, close the script's window.

Recover from a crash

• Launch the .bat file
  
• Type 2 and press ENTER
  
• A confirmation warning will appear. Press any key if you want to recover the saves. Else, close the script's window.

Once the recover is done, if you want to game again, press any key to start the backup save routine and launch Bioshock Remastered. If you don't want to play, just close the script's window.

The script

Note that the script is also available here on Gitlab[gitlab.com].

@ECHO OFF
title BIOSHOCK HD SAVE SAVER
REM ###############################################
REM ##### BEGINNING OF THE CUSTOMIZATION PART #####
REM ###############################################

REM Put below the path to your save files. 
REM Normally, this shouldn't change. But some people like to put their saves 
REM somewhere else for some reason, so this is for them.

set BS_SAVE_PATH="%USERPROFILE%\Documents\BioshockHD\Bioshock\SaveGames"

REM -----------------------------------------------
REM Put below the path to where you want to hold your backup files.
REM You normally won't need to change it, but in case you want them in a specific place...
REM Don't bother creating the folder, the script will do it for you.

set BS_BACKUP_PATH="%USERPROFILE%\Bioshock Saves"

REM ###############################################
REM ######## END OF THE CUSTOMIZATION PART ########
REM ###############################################

:MENU
ECHO.
ECHO ========================================================
ECHO =============== BIOSHOCK HD SAVE SAVER =================
ECHO ========================================================
ECHO.
ECHO  Wat do?
echo.
ECHO 	1 - I want to play and get my saves saved.
ECHO 	2 - My game crashed! I want to recover my saves!
ECHO 	3 - Exit. I launched this by mistake...
ECHO.

SET /P M=Type 1, 2, or 3 then press ENTER:
IF %M%==1 GOTO loop
IF %M%==2 GOTO recover
IF %M%==3 GOTO EOF

:loop
echo Copying save files...
IF NOT EXIST %BS_BACKUP_PATH% MKDIR %BS_BACKUP_PATH%
robocopy %BS_SAVE_PATH% %BS_BACKUP_PATH% /E
echo Done. Waiting next minute...
timeout /t 60
cls
goto loop

:recover
cls
ECHO.
ECHO 	WARNING! This might erase the save files already existing. Use this only if you just crashed on Bioshock and want to recover saves that has been removed by 2k's stupidity. If you're sure of that, press any key. Else, just close this script's window.
pause
echo Recovering save files...
robocopy %BS_BACKUP_PATH% %BS_SAVE_PATH% /E
echo 	Done! Press any key if you plan to game again right now and start the saves backup routine. Else, just close this script.
pause
goto loop

[jacob123443211]

This game also seems to have a bad memory leak from just pausing. The more you pause the higher the chance of crashing.

[LiquidBeasst]

i might be stupid... i cant understand how to do this can someone help? :(

[BallisticCrow]

Man I just beat the game and I had no idea about this script... I had to manually back up my save files after having to do the 2 final levels twice...

Will use it next time around.

[bulletshowerr]

It didnt work for me properly, but luckily i have some experience with batch script so i fixed it myself. My Bioshock is installed on another station, that was my problem. Thanks for this script and sharing.

[Bowel Loosener]

Favoriting because I had crash problems on the XB1

[TinMan1325]

Thank you. This worked

[Max le Fou]

Take the updated script and replace the variable BS_SAVE_PATH with "%HOMEDRIVE%%HOMEPATH%\OneDrive\ドキュメント\BioshockHD\Bioshock\SaveGames"

[Nyxa Clawtail]

Can you simplify this for dumb people? My file for save games is in: C:\Users\dog_m\OneDrive\ドキュメント\BioshockHD\Bioshock\SaveGames - but I keep on getting an error. Help pls. Want to play it at least once but meh.

[Ateszkoma]

When I try to lauch the .bat file I get the "This software cannot be used on your computer" message, any idea for this?

[blackwateral]

I was at the elevator in olympia heights , i saved, and then my game crashed. I thought olympia heighs was a good place to start when it froze then i launched the game again and it put me all the way back to neptunes bounty